;DDT TISKOVÁ SESTAVA

Name('Štítky na regály')
Designed('WinDUO')
Author('Marián Broda','EMail: info@3points.cz','http://www.3points.cz')
Descr('Štítky na regály do skladu','Možnost využít filtr - Ne','Změna třídění - Ne')

;*************************************************************************************************************************************
;verze

DatumZmeny :Word=ValDate('04.09.2013')  ;Datum vytvoření (změny)
Verze      :String='1.1.'               ;Vytvoření sestavy

;*************************************************************************************************************************************
;deklarace

DeclareRec('Program')

Veta       :LongInt
VetaD      :LongInt
Pos        :LongInt
Prv        :LongInt=0
Kod        :String[14]
PoziceX    :Integer=3;
PoziceY    :Integer=7;

Nadpis     :String
BudovaOD   :Integer=0;
BudovaDO   :Integer=0;
RadaOD     :Integer=0;
RadaDO     :Integer=0;
PoziceOD   :Integer=0;
PoziceDO   :Integer=0;
UrovenOD   :Integer=0;
UrovenDO   :Integer=0;

xBudova    :Integer
xRada      :Integer
xPozice    :Integer
xUroven    :Integer
xPocet     :Integer

xKod       :String

INI        :String = 'stitky.ini'

;*************************************************************************************************************************************
;nacti z ini

Nadpis   =GetFromIni('93x62','Nadpis',INI)
BudovaOD =Val(GetFromIni('93x62','BudovaOD',INI))
BudovaDO =Val(GetFromIni('93x62','BudovaDO',INI))
RadaOD   =Val(GetFromIni('93x62','RadaOD',INI))
RadaDO   =Val(GetFromIni('93x62','RadaDO',INI))
PoziceOD =Val(GetFromIni('93x62','PoziceOD',INI))
PoziceDO =Val(GetFromIni('93x62','PoziceDO',INI))
UrovenOD =Val(GetFromIni('93x62','UrovenOD',INI))
UrovenDO =Val(GetFromIni('93x62','UrovenDO',INI))

;*************************************************************************************************************************************
;formular

DefDialog('Regálové štítky 93x62 (v.'+Verze+')',500,220,True)
DlgShade(,,10,10,480,165,,ta_center)

DlgStatic(-1,'Nadpis:',20,20,80,,,,$000000)
DlgEdit(110,Nadpis,20,40,460,,70)

DlgStatic(-1,'Budova:',20,70,80,,,,$000000)
DlgEdit(120,BudovaOD,20,90,22,,2,es_right,'0123456789',0)
DlgStatic(-1,'-',49,94,10,,,,$000000)
DlgEdit(121,BudovaDO,60,90,22,,2,es_right,'0123456789',0)

DlgStatic(-1,'Řada:',120,70,80,,,,$000000)
DlgEdit(130,RadaOD,120,90,22,,2,es_right,'0123456789',0)
DlgStatic(-1,'-',149,94,10,,,,$000000)
DlgEdit(131,RadaDO,160,90,22,,2,es_right,'0123456789',0)

DlgStatic(-1,'Pozice:',220,70,80,,,,$000000)
DlgEdit(140,PoziceOD,220,90,33,,3,es_right,'0123456789',0)
DlgStatic(-1,'-',259,94,10,,,,$000000)
DlgEdit(141,PoziceDO,270,90,33,,3,es_right,'0123456789',0)

DlgStatic(-1,'Úroveň:',320,70,80,,,,$000000)
DlgEdit(150,UrovenOD,320,90,22,,2,es_right,'0123456789',0)
DlgStatic(-1,'-',349,94,10,,,,$000000)
DlgEdit(151,UrovenDO,370,90,22,,2,es_right,'0123456789',0)

DlgStatic(-1,'Levý okraj:',20,120,80,,,,$000000)
DlgEdit(201,PoziceX,20,140,33,,3,es_right,'0123456789',0)
DlgStatic(-1,'Horní okraj:',120,120,80,,,,$000000)
DlgEdit(202,PoziceY,120,140,33,,3,es_right,'0123456789',0)


DlgButton(id_Cancel,'Zpět',357,180)
DlgButton(id_OK,'OK',427,180)

Result:Integer=DlgExecute(True)

if(Result=ID_Cancel)
  Halt

;*************************************************************************************************************************************
;uloz do ini

SetToINI('93x62','Nadpis',Nadpis,INI)
SetToINI('93x62','BudovaOD',BudovaOD,INI)
SetToINI('93x62','BudovaDO',BudovaDO,INI)
SetToINI('93x62','RadaOD',RadaOD,INI)
SetToINI('93x62','RadaDO',RadaDO,INI)
SetToINI('93x62','PoziceOD',PoziceOD,INI)
SetToINI('93x62','PoziceDO',PoziceDO,INI)
SetToINI('93x62','UrovenOD',UrovenOD,INI)
SetToINI('93x62','UrovenDO',UrovenDO,INI)

;*************************************************************************************************************************************
;procedura

Procedure CRC;
  LocL:LongInt=Val(xKod)
  LocW:LongInt=0
  While(LocL<>0)
    begin
      LocW=LocW+(LocL%10)
      LocL=LocL/10
    end;
  LocW=LocW%10
  xKod=xkod+Char(Asc('0')+LocW)
end

;*************************************************************************************************************************************
;tisk

WnsType(1)

xPocet=0
xBudova=BudovaOD
while(xBudova<=BudovaDO)
  begin
    xRada=RadaOD
    while(xRada<=RadaDO)
      begin
        xPozice=PoziceOD
        while(xPozice<=PoziceDO)
          begin
            xUroven=UrovenOD
            while(xUroven<=UrovenDO)
              begin
                Inc(xPocet)
                if(xPocet>1)
                  NextPage
                FontSize(3)
                FontFace(Bold)
                XText(PoziceX,PoziceY,93-PoziceX,TA_Left|TA_BaseLine,Nadpis)
                FontFace(Normal)
                Text(PoziceX,PoziceY+6,TA_Left|TA_BaseLine,'Úroveň');   
                Text(PoziceX,PoziceY+34,TA_Left|TA_BaseLine,'Pozice');
                Text(PoziceX+24,PoziceY+42,TA_Left|TA_BaseLine,'Řada');
                FontFace(Bold)
                FontSize(35)
                Text(PoziceX,PoziceY+30,TA_Left|TA_BaseLine,xUroven);  
                FontSize(20)
                Text(PoziceX,PoziceY+50,TA_Left|TA_BaseLine,Null(xPozice,2));   
                FontSize(10)
                Text(PoziceX+21,PoziceY+50,TA_Left|TA_BaseLine,'/'+xRada);   
                FontFace(Normal)
                FontSize(5)
                ;Box(PoziceX+38,PoziceY+5,50,45)
                xKod=Null(xBudova,2)+Null(xRada,2)+Null(xPozice,3)+Null(xUroven,2)
	        CRC
                BarCode(bc_Code2of5i,PoziceX+34,PoziceY+5,60,45,xKod,True,False)
                Inc(xUroven)
              end
            Inc(xPozice)
          end
        Inc(xRada)
      end
    Inc(xBudova)
  end





END